Startseite » Foren » Reporting & Visualisierung

Karten in SAS Enterprise Guide

Reporting & Visualisierung | Eingetragen von Xilef. | 28 September, 2007 - 10:44

Hallo!

Ich möchte mit Hilfe von SAS Enterprise Guide thematische Karten für NRW erstellen. Für die benötigte Feature-Tabelle habe ich aus der germany.sas7bdat die NRW-Koordinaten selektiert. Die Erstellung von Karten funktioniert zwar, ich würde aber gerne wissen, wie man die Karten verschönern kann. Wie kann man verhindern, dass die Zahlen automatisch in Anteile aufgeteilt werden? Ich möchte die Anteilsblöcke selber bestimmen, was soll ich mit 16,20 bis 18,67, usw.? Oder wie lassen sich z.B. die Bezeichnungen der Kreise einblenden? Hm, ich finde sogar Mercator einfacher.

Danke schon mal.

Felix

Anmelden oder registrieren um Kommentare einzutragen | Vorheriges Thema | Nächstes Thema

Formate

Eingetragen von AndreasMangold. | 29 September, 2007 - 16:18

Die Landkartenfunktion in SEG bietet nur wenige Möglichkeiten. Wenn man hingegen seine eigenen SAS/GRAPH-Programme schreibt, hat man beinahe unbegrenzte Möglichkeiten. Hier ein Beispiel, das die Wertebreiche mit einem Format erzeugt. Kreisdaten habe ich leider nicht gefunden.

/* Wahlen in NRW, quelle: www.regionalstatistik.de */
data wahlen;
   length name $20 regbez $3;
   input regbez $ name $ wahlberechtigte wahlbeteiligung stimmen cducsu spd gruene fdp pds sonstige;
datalines;
051 Düsseldorf 3819145 62.7 2368831 1023942 905741 137732 154977 23208 123231
053 Köln 3131983 63.1 1953026 896194 658380 155186 142888 18133 82245
055 Münster 1950001 64.6 1247318 589354 458084 67838 66101 9588 56353
057 Detmold 1549207 63.0 965204 465595 336577 57133 53807 5465 46627
059 Arnsberg 2780030 62.1 1709635 721421 700206 91404 90493 16595 89516
;

/* NRW-Kreiskarte aus Deutschlandkarte erstellen */
data nrw_kreis;
   set maps.germany;
   where id between 5000 and 5999;
   length regbez $3;
   regbez=substr(put(id,z5.),1,3);
run;

/* auf Regierungsbezirke reduzieren */
proc gremove data=nrw_kreis out=nrw_regbez;
   by regbez;
   id id;
run;

/* Format für Wertebereiche */
proc format;
   value wb
      low-<63 = "unter 63%"
      63-<64  = "63-64%"
      64-high = "über 64%"
   ;
run;

/* Choropletendiagramm erzeugen */
proc gmap map=nrw_regbez data=wahlen;
   id regbez;
   choro wahlbeteiligung / discrete;
   format wahlbeteiligung wb.;
run;
quit;
» Anmelden oder registrieren um Kommentare einzutragen

Danke schön, die Blöcke

Eingetragen von Xilef. | 1 Oktober, 2007 - 11:48

Danke schön, die Blöcke kann ich jetzt selber erstellen. Leider fehlen immer noch die Kreisnamen. Zwar lassen sich die Bezeichnungen mit "Eigenschaften -> Etiketten -> Regionetiketten anzeigen" einblenden, aber wie geht es mit Hilfe einer Option im Programm o.ä.?

http://img299.imageshack.us/img299/8304/unbenanntoy2.png

Hm, die Kanten sind auch noch nicht optimal.

» Anmelden oder registrieren um Kommentare einzutragen