Startseite » Foren » Statistik & Data Mining

Chi-Quadrat-Test bei bereits vorhandener Kontingenztabelle

Statistik & Data Mining | Eingetragen von Stefanie Rankl. | 13 September, 2007 - 15:55

Ich habe ein Problem mit dem Chi-Quadrat-Verteilungstest mittels der Prozedur proc freq:

In meinem Datensatz liegen die Variablen bereits als Kontingenztabelle vor, also nach unten sind die Ausprägungen der Variable 1 abgetragen und nach rechts die Ausprägungen der Variablen 2. In den Zellen stehen bereits die jeweiligen Besetzungszahlen. Lt. SAS-Hilfe müssen die Daten allerdings in "Rohform" vorliegen, da ja in der tables-Option dann erst die Kreuzung gemacht wird (tables variable1*variable2).

Ich könnte natürlich jetzt die Kreuztabelle sozusagen wieder auflösen, allerdings denke ich, dass SAS das doch irgendwie trotzdem hinkriegen müsste, oder?
Ich bin für alle Tipps dankbar!

Anmelden oder registrieren um Kommentare einzutragen | Vorheriges Thema | Nächstes Thema

Chi-Quadrat-Test bei bereits vorhandener Kontingenztafel

Eingetragen von MViessmann. | 31 Januar, 2008 - 11:18

Die Daten müssen nicht unbedingt in Rohform vorliegen.
Man muss die Daten in die Form bringen, wie unten im Cards-Statement.

Dann kann man im Proc Freq und Weight die Kontingenztafel wieder erstellen und den Chi-Quadrat-Test berechnen lassen.

DATA test;
  INPUT ass yesno anz;
  CARDS;
1 1 179
1 2 81
2 1 62
2 2 18
3 1 167
3 2 13
;
RUN;
TITLE 'Chi-Quadrat-Test';
PROC FORMAT;
  VALUE fass 1=" coronary" 2="arterial" 3="venous";
  VALUE fyn 1="yes" 2="no" ;
  RUN;

PROC FREQ DATA=test;
  TABLE ass * yesno /CHISQ;
  WEIGHT anz;
  FORMAT ass fass. yesno fyn.;
RUN;

Martina Viessmann

» Anmelden oder registrieren um Kommentare einzutragen

Auflösen

Eingetragen von AndreasMangold. | 13 September, 2007 - 16:27

Mir fällt auch nur auflösen ein:

data Kontingenz;
   length var1 $1;
   input var1 $ A B C;
datalines;
X 1 2 3
Y 4 5 6
Z 7 8 9
;

data Freq (keep=var1 var2 freq);
   length var2 $1;
   set Kontingenz;
   array vars a--c;
   do over vars;
      var2 = vname(vars);
      freq = vars;
      output;
   end;
run;
» Anmelden oder registrieren um Kommentare einzutragen

Chi-square Test bei aggregierten Tabellen

Eingetragen von E. Schremmer. | 7 Dezember, 2007 - 12:11

Versuchen Sie es doch mal mit "weight" in proc freq.

viele Grüße
Ellen Schremmer

» Anmelden oder registrieren um Kommentare einzutragen