Startseite » Foren » ETL & Base SAS

Kreuztabelle als Data-Set so wie aus proc tabulate

ETL & Base SAS | Eingetragen von HansKneilmann. | 29 August, 2007 - 12:52

Hallo zusammen,
mit dem proc tabulate kann man bekanntlich wunderschön Kreuztabellen erzeugen. Aber wie kann man die schöne Ausgabe als Data Set erhalten?
Und zwar genau so wie im OUT-Fenster! Also nicht so wie z.B. die Ausgabe aus dem proc means.

Beispiel Ausgabe aus proc tabulate:

Kreuztabelle ('tabulate', je mm-Wert eine Spalte mit 'Sum(ww)')

------------------------------
|       |       Monat        |
|       |--------------------|
|       |  m1  |  m2  |  m3  |
|       |------+------+------|
|       | Wert | Wert | Wert |
|       |------+------+------|
|       |Summe |Summe |Summe |
|-------+------+------+------|
|Filiale|      |      |      |
|-------|      |      |      |
|f1     |  3,00|  4,00|  3,00|
|-------+------+------+------|
|f2     | 23,00| 66,00| 67,00|
|-------+------+------+------|
|f3     |996,00|443,00|1330,0|
------------------------------

Wunsch-Data-Set, Ausgabe mit proc print:

Obs    ff     m1     m2      m3
 1     f1      3      4       3
 2     f2     23     66      67
 3     f3    996    443    1330

Mit dem ODS oder dem out= im PROC-Statement kommt man m.E. nicht zum Ziel. Damit entsteht nur ein unschönes Data Set (Bespiel mit proc tabulate ... out=):

Obs    ff    mm    ww_Sum
 1     f1    m1        3
 2     f1    m2        4
 3     f1    m3        3
 4     f2    m1       23
 5     f2    m2       66
 6     f2    m3       67
 7     f3    m1      996
 8     f3    m2      443
 9     f3    m3     1330

Erste Frage: Geht das?

Zweite Frage: Wie geht das wenn man doppel- oder dreifach-Spalten je mm-Wert hat?
Beispiel für dreifach-Spalten: sum(ww) mean(ww) und n(ww).

Eine umständliche Variante habe ich auch schon (s.u.), aber die gefällt mir nicht! Es muss doch auch einfach gehen.
Aber wie???

Das war sozusagen die Einleitung, jetzt kommt die "Lang-Version" mit Beispiel-Daten, Beispiel-Code und allem drum und dran.

Beispiel-Code :

DATA tmp_SD0;            /* Test-Daten */
  input ff $2. mm $2. ww;
cards;
f1m10
f1m11
f1m12
f1m21
f1m23
f1m33
f2m111
f2m112
f2m221
f2m222
f2m223
f2m333
f2m334
f3m1331
f3m1332
f3m1333
f3m2221
f3m2222
f3m3331
f3m3332
f3m3333
f3m3334
;
run;
title2 "Kreuztabelle ('tabulate', je mm-Wert eine Spalte mit 'Sum(ww)')";
options linesize=80;
PROC TABULATE DATA=tmp_SD0;
    CLASS ff mm;                        /* Gruppierungs-Variablen */
    VAR   ww;                           /* ww ist für Zellen-Summe */
    TABLE
          ff                            /* "runter" */
          ,
          mm *(ww*SUM*f=commax6.2)      /* "quer", je mm-Wert eine Spalte */
          / rts=9                       /* rts == RowTableSize       */
                                        /*     == Breite d.TextSpalte */
    ;
    keylabel SUM='Summe';
    label
        ff='Filiale'
        mm='Monat'
        ww='Wert'
    ;
RUN;
Beispiel-Ausgabe: Siehe oben bei "Beispiel Ausgabe aus proc tabulate:"

Wie kann man diese schöne Ausgabe als Data Set erhalten? Und zwar genau so wie im OUT-Fenster! Also nicht so:

Obs    ff    mm    ww_Sum
 1     f1    m1        3
 2     f1    m2        4
 3     f1    m3        3
 4     f2    m1       23
 5     f2    m2       66
 6     f2    m3       67
 7     f3    m1      996
 8     f3    m2      443
 9     f3    m3     1330

sondern so

Obs    ff     m1     m2      m3
 1     f1      3      4       3
 2     f2     23     66      67
 3     f3    996    443    1330

Gefunden bzw. ausgetüfftelt habe ich bisher eine proc tabulate... out= mit proc transpose-Lösung. Meine Lösung ist so:

PROC TABULATE DATA=tmp_SD0 out=tmp_SD1(drop=_TYPE_ _PAGE_ _TABLE_);
    CLASS ff mm;            /* Gruppierungs-Variablen  */
    VAR   ww;                  /* ww ist für Zellen-Summe */
    TABLE
          ff                /* "runter" */
          ,
          mm *(ww*SUM*f=commax6.2)      /* "quer", je mm-Wert eine Spalte    */
          / rts=9                      /* rts == RowTableSize               */
    ;
    keylabel SUM='Summe';
    label
        ff='Filiale'
        mm='Monat'
        ww='Wert'
    ;
RUN;
proc transpose data=tmp_SD1  out=tmp_SD3(drop=_name_);
  by ff;
  id mm;
run;
title2 "Kreuztabelle als Data-Set wie aus proc tabulate ";
title3 "   (Kreuztabelle je mm-Wert eine Spalte mit 'Sum(ww)')";
proc print data=tmp_SD3;
run;
Erste Frage (s.o.): Geht das auch ohne Umwege auf direktem Weg?

Zweite Frage (s.o.): Wie geht das wenn doppel- oder dreifach-Spalten je mm-Wert hat?
Beispiel für dreifach-Spalten: sum(ww) mean(ww) und n(ww).

Die umständliche Variante (s.u.) gefällt mir ganz und gar nicht! Es muss doch auch besser gehen, z.B. mit einem proc tabulate und einem proc transpose und fertig. Aber wie???

Code der umständlichen Variante:
Der Code steht hier

Ausgabe dazu (Auszug):

Kreuztabelle ('tabulate', je mm-Wert eine Doppel-Spalte mit 'Sum(ww) + Mean(ww)')

---------------------------------------------------
|       |                  Monat                  |
|       |-----------------------------------------|
|       |     m1      |     m2      |     m3      |
|       |-------------+-------------+-------------|
|       |      | Wert |      | Wert |      | Wert |
|       | Wert |------| Wert |------| Wert |------|
|       |------|Mitte-|------|Mitte-|------|Mitte-|
|       |Summe |lwert |Summe |lwert |Summe |lwert |
|-------+------+------+------+------+------+------|
|Filiale|      |      |      |      |      |      |
|-------|      |      |      |      |      |      |
|f1     |  3,00|  1,00|  4,00|  2,00|  3,00|  3,00|
|-------+------+------+------+------+------+------|
|f2     | 23,00| 11,50| 66,00| 22,00| 67,00| 33,50|
|-------+------+------+------+------+------+------|
|f3     |996,00|332,00|443,00|221,50|1330,0|332,50|
---------------------------------------------------

Gesamt-Kreuztabelle als Data-Set wie aus proc tabulate 
   (Kreuztabelle je mm-Wert eine DoppelSpalte mit 'Sum(ww) + Mean(ww)')

Obs    ff    sum_m1    sum_m2    sum_m3    mean_m1    mean_m2    mean_m3

 1     f1        3         4         3        1.0        2.0        3.0
 2     f2       23        66        67       11.5       22.0       33.5
 3     f3      996       443      1330      332.0      221.5      332.5

Abgesehen davon, dass die Spalten zu Monat m1, m2, ... nicht mehr als Gruppe zusammen stehen kann man mit der Lösung leben, aber umständlich ist sie schon und schlanker wäre ganz einfach besser!!!
Gruß
Hans Kneilmann, Schäfer Shop GmbH (SSI)

Nachtrag, 16.11.2007: Es geht einfacher, siehe Beitrag unten und siehe 2. Datei im Anhang

Anmelden oder registrieren um Kommentare einzutragen | Vorheriges Thema | Nächstes Thema

Wohl leider nicht...

Eingetragen von Jobst Heitzig. | 10 Oktober, 2007 - 17:14

Das Problem kenne ich schon länger und glaube, dass es keine einfachere Lösung als die bereits hier genannten gibt.

Bei anderen Prozeduren als Proc Tabulate kann man mitunter eine SAS-Datei bekommen, die wie eine bestimmte ODS-Tabelle aussieht, in dem man mit ODS OUTPUT ODS-Pfadname=SAS-Datei arbeitet, aber bei Proc Tabulate ergibt das leider nur eine "linearisierte" Datei wie bei OUT=...;

» Anmelden oder registrieren um Kommentare einzutragen

Es geht auch kompakter

Eingetragen von KlausLandwich. | 9 Oktober, 2007 - 13:44

Mit zwei Transpose und einem DataStep dazwischen kommt man auf das gleiche Ergbenis wenn man Summe und Mittelwert verwendet.

Mit dem ersten Transpose sorgt man für eine einzige Wertespalte. Mit dem DataStep defniert man sich eine ID-Variable, die man im nächsten Transpose dann verwendet.

Ich dachte zuerst mit ODS Output bekäme man ein besseres Ergebnis. Dem ist leider nicht so.

Hier das Programm (inkl. ODS Output)

DATA tmp_SD0;            /* Test-Daten */
  input ff $2. mm $2. ww;
cards;
f1m10
f1m11
f1m12
f1m21
f1m23
f1m33
f2m111
f2m112
f2m221
f2m222
f2m223
f2m333
f2m334
f3m1331
f3m1332
f3m1333
f3m2221
f3m2222
f3m3331
f3m3332
f3m3333
f3m3334
;
run;
title2 "Kreuztabelle ('tabulate', je mm-Wert eine Spalte mit 'Sum(ww)')";
options linesize=80;
ods trace on;
ods output Table=work.test;
ods html file="C:\TEMP\Test.html";
PROC TABULATE DATA=tmp_SD0 out=work.test1;
    CLASS ff mm;                        /* Gruppierungs-Variablen */
    VAR   ww;                           /* ww ist für Zellen-Summe */
    TABLE
          ff                            /* "runter" */
          ,
          mm *(ww*SUM*f=commax6.2 ww*Mean*f=commax6.2)      /* "quer", je mm-Wert eine Spalte */
          / rts=9                       /* rts == RowTableSize       */
                                        /*     == Breite d.TextSpalte */
    ;
    keylabel SUM='Summe';
    label
        ff='Filiale'
        mm='Monat'
        ww='Wert'
    ;
RUN;
ods html close;
ods output close;
/* Nur ein numerische Wert und sonst nur ClassVars */
proc transpose data=work.test1 (drop=_page_ _table_ _type_) out=work.test2;
   by ff mm;
run;
/* ID-Spalte erzeugen... */
data work.test3;
   set work.test2;
   transposeid=mm!!_NAME_;
run;
/* ... und verwenden */
proc transpose data=work.test3 out=work.test4 (drop=_NAME_);
   by ff;
   id transposeid;
run;

Was man sieht ist, dass das Programm nur mit den Classvariablen auskommt. Das heissst selbst wenn man drei oder vier Spalten pro mm hat braucht das Programm nicht angepasst zu werden.

Gruß
Klaus Landwich

» Anmelden oder registrieren um Kommentare einzutragen

kompakter !!!

Eingetragen von HansKneilmann. | 16 November, 2007 - 13:06

Hallo,
das war genau das was ich mir erhoffte!
Es hat nur "ein paar" Tage gedauert bis ich Zeit hatte die kompakte Version mit meiner Version zu vergleichen (meine Version steht hier und in der Redscope-Makro-Sammlung, unter: org.redscope.HansKneilmann.KreuzTabAlsDataSet) und sie dann so umzubauen, dass ich die kompakte Version gegen die alte umständlichere Version austauschen konnte.

Das Ergebnis findet sich in der Redscope-Makro-Sammlung, der Eintrag lautet: org.redscope.HansKneilmann.KreuztaY_ds

Vielen Dank nochmal an Klaus Landwich!

Gruß
Hans Kneilmann, Schäfer Shop GmbH (SSI)

» Anmelden oder registrieren um Kommentare einzutragen

lustigerweise hatte ich

Eingetragen von NicoHaag. | 29 August, 2007 - 16:49

lustigerweise hatte ich vorgestern genau das gleiche problem.
jedoch sieht meine lösung genauso aus, also über den umweg mit der proc transpose. was besseres hab ich auch noch nicht gefunden...

» Anmelden oder registrieren um Kommentare einzutragen

ODS EXCELXP?

Eingetragen von Jobst Heitzig. | 3 September, 2007 - 14:27

Vielleicht einmal mit ODS eine Excel-Datei erzeugen und die wieder mit proc import importieren? Ist allerdings nur eine Idee...

» Anmelden oder registrieren um Kommentare einzutragen

Danke

Eingetragen von HansKneilmann. | 8 Oktober, 2007 - 15:03

Hallo,
danke für die ODS-Excel-Idee,
aber ich wollte eine einfache Lösung. Wenn schon umständlich, dann kann ich auch eine umständlich aber reine SAS-Lösung nehmen ...
Als Macro ist sie hier in der Redscope-Makro-Sammlung zu finden. In der Gruppe
-->> org.redscope.HansKneilmann.*
dort der Macro
-->> org.redscope.HansKneilmann.KreuzTabAlsDataSet

Gruß
Hans Kneilmann, Schäfer Shop GmbH (SSI)

» Anmelden oder registrieren um Kommentare einzutragen