Startseite » Foren » ETL & Base SAS

Dynamische KEEP- oder DROP-Listen

ETL & Base SAS | Eingetragen von MM Genepi. | 14 August, 2007 - 16:39

Hallo,

folgende Frage scheint im Forum noch nicht diskutiert worden zu sein:

Ich habe ein Array x[500], wobei nur wenige Felder einen von 1000 abweichenden Wert haben. Am Schluss des DataSteps möchte ich nur diese Felder xi behalten, deren Inhalt < 1000 ist.
(Hintergrund ist übrigens, für den Export nach Excel nur solche Spalten zu behalten, die wirklich relevante Informationen enthalten.)

Es ist nun nicht schwierig, einen String mit der Liste aller Felder zu erzeugen, deren Inhalt

Anmelden oder registrieren um Kommentare einzutragen | Vorheriges Thema | Nächstes Thema

Hat das dataset eine oder

Eingetragen von MWendel. | 14 August, 2007 - 17:09

Hat das dataset eine oder mehrere Sätze?

» Anmelden oder registrieren um Kommentare einzutragen

So müsste es gehen:

Eingetragen von MWendel. | 14 August, 2007 - 18:55

So müsste es gehen:

options nosource mprint;
%let obs = 5;
%let len = 10;
%let value = 10;
%macro bla;
    data test; %* hier wird das dataset generiert;
        array d (&len);
        drop i j r;
        do J = 1 to &obs;
            do i = 1 to &len;
                r = ranuni(1);

                if r < 0.95 then
                    d(I) = &value;
                else
                    d(I) = &value - i;
            end;
            output;
        end;

    proc print;

    data test; %* hier wird die verarbeitung vorbereitet;
        array d (&len) ;
        array f (&len) _temporary_ (%do I = 1 %to &len; 0 %end;) ;
        set test end = End;
        do i = 1 to &len;
            f(i) = f(i) or d(i) < &value;
        end;
        do i = 1 to &len;
            f(i) = f(i) or d(i) < &value;
        end;
        if End then do i = 1 to &len;
            call symput('f' !! trim(left(put (i, best.))), compress(put(f(i), best.)));
        end;
    run;

    %do I = 1 %to &len;
        %put f&i = &&f&i;
    %end;

    proc print;

    data test; %* hier wird die verarbeitung durchgeführt;
        set test (keep = %do I = 1 %to &len;
                                  %if &&F&I %then D&I;
                              %end;);
    run;

    proc print;
    run;
%mend;
%bla
options source ;
» Anmelden oder registrieren um Kommentare einzutragen

Vielen Dank, MWendel!

Eingetragen von MM Genepi. | 15 August, 2007 - 08:51

Vielen Dank, MWendel!

Das funktionierende Testbeispiel werde ich auf den Fall anwenden.
Eine Frage habe ich noch:
Ich verstehe nicht, was der zweite, völlig identische Aufruf der drei Zeilen

do i = 1 to &len;
    f(i) = f(i) or d(i) < &value;
end;

bewirken soll, da f(i) bei erfüllter Bedingung bereits nach dem ersten Durchlauf 1 ist.

Gruß
MM

» Anmelden oder registrieren um Kommentare einzutragen

Das war ein copy und

Eingetragen von MWendel. | 15 August, 2007 - 15:14

Das war ein copy und paste-Fehler.
Gruß,
M. Wendel

» Anmelden oder registrieren um Kommentare einzutragen

Mehrere Sätze

Eingetragen von MM Genepi. | 14 August, 2007 - 17:16

Das Dataset hat mehrere (9) Sätze.
Was ich zur Vereinfachung weggelassen hatte:
Ich habe vor, alle Beobachtungen durchzugehen und je Spalte ein Flag zu setzen, wenn irgendwo ein Wert

x[i] LT 1000
auftritt.

MM

» Anmelden oder registrieren um Kommentare einzutragen

Pardon! Fortsetzung

Eingetragen von MM Genepi. | 14 August, 2007 - 16:51

Leider ist mir beim Speichern der Rest des Beitrages abhanden gekommen. Also:

"Es ist nun nicht schwierig, einen String mit der Liste aller Felder zu erzeugen, deren Inhalt LT 1000 ist.

list = '';
DO i=1 TO 500;
    IF (x[i] LT 1000) THEN DO;
        list = catt(list, ' x',i);
    END;
END;

Aber wie kann ich mit dieser Liste KEEP oder DROP steuern?
Verwende ich einen Makro, bereitet mir die Konkatenierung der Liste Schwierigkeiten (Einbringen des Laufindizes i).

Für einen Hinweis wäre ich dankbar.
Gruß

Meinhard Mende

» Anmelden oder registrieren um Kommentare einzutragen

Kein Problem mit call symput

Eingetragen von HansKneilmann. | 15 August, 2007 - 09:18

Hallo,
unabhängig davon, dass weiter oben das eigentliche Problem schon gelöst ist, will ich trotzdem hier noch die Lösung (?) zu dem "kleinen" Problem "Verwende ich einen Makro, bereitet mir die Konkatenierung der Liste Schwierigkeiten (Einbringen des Laufindizes i)" aus dem Beitrag von MM Genepi, 14. August 2007, 16:51 beisteuern:
Einfach nach der DO-Schleife einen call SYMPUT machen und schon ist die Variablen-Liste 'da' um sie in einer keep-Liste einzusetzen:

DATA blalbla_out;
  set blabla_in;
  /* ..... */
  list = '';
  DO i=1 TO 500;
    IF (x[i] LT 1000) THEN DO;
      list = catt(list, ' x',i);
    END;
  END;
  call symput(KeepVars, compress(list)); /* compress eigenlich unnötig */
run;
%put INFO: KeepVars=&KeepVars.;  /* Kontroll-Ausgabe im log */
Die Lösung erscheint mir soooo einfach, dass ich befürchte ich habe irgendetwas falsch verstanden ....
Gruß
Hans Kneilmann, Schäfer Shop GmbH (SSI)

» Anmelden oder registrieren um Kommentare einzutragen

Den Wald vor Bäumen nicht gesehen ...

Eingetragen von MM Genepi. | 15 August, 2007 - 10:03

Vielen Dank, Hans Kneilmann!

Der Zusammenhang ist tatsächlich noch komplexer als im Beitrag dargestellt, da x hier doppelt indiziert ist.
(Das erschwert aber kaum die Listenerstellung, indem man den Index k aus i und j berechnet.)
Außerdem habe ich mich wohl davon "schocken" lassen, dass die Variablenliste erst im nächsten DataStep zur Verfügung steht, was aber auch kein Problem ist.
Ich danke nochmals, da solche Hinweise helfen, cleverer mit den gegebenen Mitteln umzugehen.

Gruß
Meinhard Mende

» Anmelden oder registrieren um Kommentare einzutragen

Macro-Var mit keep-Liste

Eingetragen von HansKneilmann. | 15 August, 2007 - 11:57

Hallo,
statt in meinem Beispiel oben die Daten einzulesen und wieder auszugeben um die Macro-Variable zu erzeugen, also statt

DATA blalbla_out;
  set blabla_in;
  /* ..... */
run;
kann man auch die Macro-Variable mit den Namen für die keep-Liste in einem data _null_-Schritt erzeugen:
DATA _null_;
  set blabla_in;
  /* ..... */
  list = '';
  DO i=1 TO 500;
    IF (x[i] LT 1000) THEN DO;
      list = catt(list, ' x',i);
    END;
  END;
  call symput(KeepVars, compress(list)); /* compress eigentlich unnötig */
run;
%put INFO: KeepVars=&KeepVars.;  /* Kontroll-Ausgabe im log */
DATA blalbla_out;
  set blabla_in(keep=&KeepVars.);
run;
Vorteil: Man bewegt nicht unnötig viele Daten.
Gruß
Hans Kneilmann, Schäfer Shop GmbH (SSI)

» Anmelden oder registrieren um Kommentare einzutragen

Einige Anregungen

Eingetragen von AndreasMangold. | 15 August, 2007 - 23:34

Der Herr Kneilmann weiß natürlich, wie das geht, und hat diese kurze und knackige Lösung einfach hingeschrieben, ohne sie auszuprobieren.

Für diejenigen, die es selbst probieren wollen:

Die Variable list muss deklariert werden (z.B. LENGTH list $200;) bevor ihr ein Wert zugewiesen wird.

In Call symput muss man den Namen der Makrovariablen in Gänsefüßchen schreiben und das compress weglassen, denn es wirft die Leerzeichen zwischen den Variablennamen wieder raus. Also:
call symput ("KeepVars", list);

Aber interessant die Verwendung von catt. Die cat-Funktionen wären mal einen Artikel wert.

» Anmelden oder registrieren um Kommentare einzutragen

Vielen Dank für die Anregungen

Eingetragen von MM Genepi. | 16 August, 2007 - 10:54

Allen Teilnehmern herzlichen Dank für die Beiträge.
Es gibt immer wieder Tipps, die "das Leben mit SAS" leichter gestalten.

Freundliche Grüße und einen guten Tag
Meinhard Mende

» Anmelden oder registrieren um Kommentare einzutragen

Mea Culpa

Eingetragen von HansKneilmann. | 16 August, 2007 - 07:52

Guten Morgen,
na klar!!
Macro-Namen im call symput immer in Gänsefüßchen und die compress-Funktion ist an der Stelle super-ober-hyper-falsch!!! :-\
Mea Culpa
Gruß
Hans Kneilmann, Schäfer Shop GmbH (SSI)

» Anmelden oder registrieren um Kommentare einzutragen

Hat das dataset einen oder

Eingetragen von MWendel. | 14 August, 2007 - 17:13

Hat das dataset einen oder mehrere Sätze?

» Anmelden oder registrieren um Kommentare einzutragen