Startseite » Foren » Statistik & Data Mining

Aus zwei Datein eine machen...

Statistik & Data Mining | Eingetragen von StephanieCGross. | 18 Mai, 2007 - 12:23

Ich habe eine Datei "Vater" und eine Datei "Kind" mit jeweils einer Haushalts-ID-Nummer, drei Variablen Tag 1, Tag 2 und Tag 3 sowie anderen ökonomischen Variablen.
Ich möchte aus diesen beiden Dateien eine einzige machen, indem die Dateien anhand der Haushalts-ID zu einer "Familie" zusammengefügt werden. Jeder Vater hat nur ein Kind.

Mein Problem: Vater und Kind sollen nur eine "Familie" bilden, wenn die Werte für Tag1 und/oder Tag 2 und/oder Tag 3 übereinstimmen. In der Familien-Datei sollen dann alle Variablen für beide enthalten sein (also Tag1 vom Kind und Tag1 vom Vater etc.), obwohl sie denselben Namen haben. Geht das?

Außerdem hätte ich noch gern einen Zähler eingebaut, der aussagt, ob ein, zwei oder alle Tage übereinstimmen...
Bitte um Hilfe!

Anmelden oder registrieren um Kommentare einzutragen | Vorheriges Thema | Nächstes Thema

Beispieldatenausschnitt

Eingetragen von AndreasMangold. | 18 Mai, 2007 - 16:29

Ist das so zu verstehen, dass Vater und Kind verbunden werden sollen, wenn mindestens ein Tag übereinstimmt? Kann ein Kind zu mehreren Vätern zugeordnet werden und kann ein Vater mehrere Kinder haben?

Ein paar Beispieldatensätze wären hilfreich.

» Anmelden oder registrieren um Kommentare einzutragen

Genauer

Eingetragen von StephanieCGross. | 18 Mai, 2007 - 18:53

Also, ein Kind kann nur einen Vater haben und ein Vater nur ein Kind. Das es sich um dieselbe Familie handelt, erkennt man an derselben HaushaltsID. Jedes Kind und jeder Vater haben darüberhinaus eine eigene eindeutige Personennummer.
Vater und Kind sollen verbunden werden, wenn wenigstens ein Tag übereinstimmt. Drei Tage wurden pro Person angegeben.
Der Tag wird durch WT (Wochentag 1-7), Quartal (1-4) und Jahr (2001 oder 2002) bestimmt. Es gibt also die Variablen WT1-WT3, Quartal1-Quartal3 und Jahr1-Jahr3...so dass jeder der drei TAge eindeutig charakterisiert ist.
Eine Übereinstimmung liegt nur vor, wenn WT, Quartal und Jahr von Kind und Vater übereinstimmen.
Ideal wäre es, wenn ein Zähler angeben würde, wieviele Tage übereinstimmen.
Für jedes Kind und jeden Vater gibts außerdem Variablen wie Alter, Einkommen, (besuchte) Schulform, die für beide denselben Namen haben. In der neuen, gemeinsamen VaterKind-Datei sollen die Variablen für BEIDE enthalten bleiben. Müssen die Variablen für Kind oder Vater umbenannt werden (wenn ja: wie nenne ich WT1 in Tag1 um?) oder können in der Enddatei zwei Variablen denselben Namen tragen.

» Anmelden oder registrieren um Kommentare einzutragen

rename

Eingetragen von AndreasMangold. | 19 Mai, 2007 - 10:04

Man kann die Variablen mit RENAME umbenennen.
Das folgende Verfahren setzt voraus, dass die beiden Dateien nach der HHID sortiert sind und dass keine n-zu-m-Beziehungen vorkommen.

data vater;
   input hhid persnr tag1 tag2 tag3 alter einkommen;
   informat tag1-tag3 ddmmyy10.;
   format tag1-tag3 ddmmyyp10.;
datalines;
1 1001  1.1.2004  2.2.2004  3.3.2004 44 30000
2 1002  1.1.2005  2.2.2005  3.3.2005 54 40000
3 1003  1.1.2006  2.2.2006  3.3.2006 64 50000
4 1004  1.1.2007  2.2.2007  3.3.2007 74 20000
;

data kind;
   input hhid persnr tag1 tag2 tag3 alter einkommen;
   informat tag1-tag3 ddmmyy10.;
   format tag1-tag3 ddmmyyp10.;
datalines;
1 2001 11.1.2004  2.2.2004  3.3.2004 14   500
2 2002 11.1.2005 12.2.2005  3.3.2005 24 15000
3 2003 11.1.2006 12.2.2006 13.3.2006 34 30000
5 2005  1.1.2007  2.2.2007  3.3.2007 44 35000
;

data familie;
   merge
      vater (in=in1
             rename=(persnr=persnr_v
                     tag1=tag1_v
                     tag2=tag2_v
                     tag3=tag3_v
                     alter=alter_v
                     einkommen=einkommen_v
                    )
            )
      kind  (in=in2
             rename=(persnr=persnr_k
                     tag1=tag1_k
                     tag2=tag2_k
                     tag3=tag3_k
                     alter=alter_k
                     einkommen=einkommen_k
                    )
            )
   ;
   by hhid;
   zaehler = (tag1_v=tag1_k) + (tag2_v=tag2_k) + (tag3_v=tag3_k);
   if in1 and in2 and zaehler>0;
run;
» Anmelden oder registrieren um Kommentare einzutragen