data feiertage(keep=start fmtname label type);
length start $10;
retain fmtname 'feiertg' type 'c' label '0';
/* Datumsfixe Feiertage inkl. Heiligabend und Sylvester */
/* Neujahr, Maifeiertag, Tag der dt. Einheit, Heiligabend, 1.+2. Weihnachtsfeiertag, Sylvester */
array _feststehend(7) $ _temporary_ ('0101' '0105' '0310' '2412' '2512' '2612' '3112');
/* Datumsvariable bundeseinheitliche Feiertage, rel. zu Ostersonntag in Tagen */
/* Karfreitag, Ostermontag, Christi Himmelfahrt und Pfingstmonatg . */
array _beweglich(4) _temporary_ (-2 1 39 50);
format start;
do Jahr = 1990 to 2100;
/* Bundeseinheitliche feststehende Feiertage inkl. Heiligabend und Sylvester */
do i = 1 to 7;
monat=input(substr(_feststehend(i),3,2),2.);
tag=input(substr(_feststehend(i),1,2),2.);
start=put(mdy(monat,tag,jahr),ddmmyyp10.);
output;
end; /*************************************************************/
/* S.a. Wikipedia "Gauß'sche Osterformel" -> ergänzte Formel */
/* nach Lichtenberg */
/*-----------------------------------------------------------*/
A=mod(Jahr,19); /* Mondparameter */
K=floor(Jahr/100); /* Säkularzahl */
M=15+floor((3*K+3)/4)-floor((8*K+13)/25); /* Säkulare Mondschaltung */
D=mod(19*A+M,30); /* Keim für den ersten Vollmond im Frühling */
S=2-floor((3*K+3)/4); /* Säkulare Sonnenschaltung */
R=floor(D/29)+(floor(D/28)-floor(D/29))*floor(A/11); /* Kalendarische Korrekturgröße */
OG=21+D-R; /* Ostergrenze */
SZ=7-mod(Jahr+floor(Jahr/4)+S,7); /* Erster Sonntag im März */
OE=7-mod(OG-SZ,7); /* Osterentfernung vom ersten Sonntag im März in Tagen */
OS=OG+OE; /* Ostersonntag als Märzdatum (32. März = 1.April) */
/*************************************************************/
if OS>31 then do;
tag=OS-31;
monat=4;
do j = 1 to 4;
start=put(intnx('day',mdy(monat,tag,jahr),_beweglich(j)),ddmmyyp10.);
output;
end;
end;
else do;
tag=OE;
monat=3;
do j = 1 to 4;
start=put(intnx('day',mdy(monat,tag,jahr),_beweglich(j)),ddmmyyp10.);
output;
end;
end;
end;
start='other';
label='1';
output;
run;
proc format cntlin=feiertage lib=work;
run;
proc format;
value wtag
1 = '0' /* Sonntag */
7 = '0' /* Samstag */
other = '1' /* Wochentage */
;
run;

data test;
input von bis;
informat von bis ddmmyy10.;
cards;
01.12.2010 31.12.2010
01.01.2011 28.02.2011
01.04.2011 01.05.2011
;
run;

data arbeitstage(keep=von bis arbeitstage);
set test;
arbeitstage=0;
format von bis ddmmyyp10.;
do i = von to bis;
arbeitstage=arbeitstage+input(put(put(i,ddmmyyp10.),$feiertg.),1.)*input(put(input(put(i,weekday.),1.),wtag.),1.);
end;
run;